Assassin's Creed II (pck)

[pietastesgood]

The contents of this post was deleted because of possible forum rules violation.

[CMihai]

the file it's from xbox360 ?

[OrangeC]

its a 360 file, but i cant figure this out either.

[GameZelda]

Code: Select all

# script for QuickBMS http://aluigi.org/papers.htm#quickbms

Endian big

# Main header
IDString "AKPK"
Get HEADER_TOTAL_SIZE long
Get HEADER_UNK1 long
If HEADER_UNK1 != 1
	Print "Strange HEADER_UNK1 = %HEADER_UNK1%, may crash..."
EndIf
Get HEADER_EXTRA_DATA_SIZE long
Get SIZE_OF_BLOCK1 long
Get SIZE_OF_BLOCK2 long

SavePos TEMP_POS
Math TEMP_POS += HEADER_EXTRA_DATA_SIZE
GoTo TEMP_POS

# Block 1
Set EXTRACT_BLOCK_BASE_PATH string "1"
CallFunction EXTRACT_BLOCK

# Block 2
Set EXTRACT_BLOCK_BASE_PATH string "2"
CallFunction EXTRACT_BLOCK

# Function to extract a block
# Set EXTRACT_BLOCK_BASE_PATH to the path where the files should be extracted before calling
StartFunction EXTRACT_BLOCK
	Get BLOCK_NUM_ENTRIES long

	For I = 0 < BLOCK_NUM_ENTRIES
		# Read the file entry
		Get ENTRY_ID long
		Get ENTRY_BLOCK_SIZE long
		Get ENTRY_UNK1 long
		If ENTRY_UNK1 != 0
			Print "Strange ENTRY_UNK1 = %ENTRY_UNK1%, may crash..."
		EndIf
		Get ENTRY_SIZE long
		Get ENTRY_OFFSET_IN_BLOCKS long
		Get ENTRY_UNK2 long
		If ENTRY_UNK2 != 0
			If ENTRY_UNK2 != 1
				Print "Strange ENTRY_UNK2 = %ENTRY_UNK2%, may crash..."
			EndIf
		EndIf

		# Extract
		Set PATH EXTRACT_BLOCK_BASE_PATH
		String PATH += "/"
		String PATH += ENTRY_ID

		Set OFFSET ENTRY_OFFSET_IN_BLOCKS
		Math OFFSET *= ENTRY_BLOCK_SIZE

		Log PATH OFFSET ENTRY_SIZE
	Next I
EndFunction

It will create 2 folders, the first one contains BKHD files (I found some info about them, it did almost match the data, but the format seems to be updated) and some RIFX files that seem to contain a headerless Ogg.

[OrangeC]

So its not possible to do anything with these RIFX files?

[GameZelda]

No, unless someone figures out how it's packed, probably they're just vorbis packets.

[hcs]

I finished a Audiokinetic Wwise RIFF/RIFX Vorbis to Ogg Vorbis converter yesterday, ww2ogg here http://hcs64.com/vgm_ripping.html

(All interested parties already know, but I thought it'd be best to give this thread closure)

[OrangeC]

And you have worked your magic hcs

[pietastesgood]

Indeed.