Otomedius G pak container.

[youngmark]

Hi
I'd like to extract *.pak file from Otomedius G.
Could anyone look into these formats please?

[aluigi]

the script is the following but I have not understood why the files you uploaded have extension "unpacked" and not "pak":

Code: Select all

# Otomedius
# script for QuickBMS http://quickbms.aluigi.org

get PATH basename
get FULLSIZE asize
do
    getdstring SIGN 4
    if SIGN == "TXGP"
        get DUMMY long
        get FILES long
        savepos BASE_OFF
        for i = 0 < FILES
            get OFFSET long
            putarray 0 i OFFSET
        next i
        for i = 0 < FILES
            get SIZE long
            putarray 1 i SIZE
        next i

        for i = 0 < FILES
            getarray OFFSET 0 i
            getarray SIZE 1 i
            math OFFSET += BASE_OFF
            goto OFFSET
            get NAME string
            padding 4
            callfunction DUMPA 1
        next i
    elif SIGN == "MESH"
        get SIZE long
        get DUMMY long
        get NAMESZ long
        get XSIZE long
        getdstring NAME NAMESZ
        math SIZE -= NAMESZ
        callfunction DUMPA 1
    elif SIGN == "CONF"
        get SIZE long
        set NAME string "conf.ini"
        callfunction DUMPA 1
    else
        print "unsupported type %SIGN% at offset %OFFSET|x%"
        cleanexit
    endif
while OFFSET < FULLSIZE

startfunction DUMPA
    savepos OFFSET
    if NAME == ""
        set FNAME string ""
    else
        set FNAME string PATH
        string FNAME += /
        string FNAME += NAME
    endif
    log FNAME OFFSET SIZE
    math OFFSET += SIZE
    goto OFFSET
endfunction

[youngmark]

Thanks aluigi!!!!!!!

[Nigoli]

Sorry to bump an old topic.



I've been having trouble with the DLC .pak files. Here's around a 1MB sample of one of the pak files. Thanks.