XeNTaX

Posted: **Tue Jan 12, 2010 2:09 pm**

Hello everyone,
I need help for JX3ONLINE .It is a cool and beautiful game.Who can help me take a look at the game's files.
Here some pictures:

33333_1.gif

The game's website:http://jx3.xoyo.com/
This is a link to the client ：http://jx3.client.cdn3.kingsoft.com/jx3_v1.4.0.1820.rar
Thanks。

Posted: **Tue Jan 12, 2010 2:12 pm**

mt11.gif

Posted: **Tue Jan 12, 2010 2:20 pm**

just fyi, if you don't upload one of the archives nobody will ever take a look at it

Posted: **Tue Jan 12, 2010 3:16 pm**

aluigi wrote:just fyi, if you don't upload one of the archives nobody will ever take a look at it

I agree. We don't want to be forced to install a game just to look at the files. I only do that when it is clear I really need to take a look at the executable while the game is running to find an algorithm of some kind.

Upload an example file somewhere.

Posted: **Wed Jan 13, 2010 11:58 am**

The contents of this post was deleted because of possible forum rules violation.

Posted: **Wed Jan 13, 2010 3:14 pm**

job done, the following is the script for quickbms

Code: Select all

# script for QuickBMS http://aluigi.org/papers.htm#quickbms

comtype NRV2b
idstring PACK
get FILES long
get INFO_OFF long
get BASE_OFF long
goto INFO_OFF
for i = 0 < FILES
    get CRC long
    get OFFSET long
    get SIZE long
    get ZSIZE long

    set doit long 0
    if CRC == -360607879    # some files are invalid!
    #elif CRC == 12345678   # put their crc/name here
    else                    # for skipping them!
        set doit long 1
    endif

    if doit != 0
        if ZSIZE & 0x10000000
            math ZSIZE &= 0x0fffffff
            callfunction unpack_0x10000000
        elif ZSIZE & 0x20000000
            math ZSIZE &= 0x0fffffff
            clog CRC OFFSET ZSIZE SIZE
        elif ZSIZE & 0x40000000
            print "Error: type 0x40000000 not supported"
            cleanexit
        elif ZSIZE & 0x80000000
            print "Error: type 0x80000000 not supported"
            cleanexit
        else
            log CRC OFFSET SIZE
        endif
    endif
next i

startfunction unpack_0x10000000
    savepos TMP
    goto OFFSET
    get CHUNKS long
    get CHUNKS_OFFSET long
    math CHUNKS_OFFSET += OFFSET
    goto CHUNKS_OFFSET
    putvarchr MEMORY_FILE SIZE 0    # pre-allocate for speed
    log MEMORY_FILE 0 0             # reset
    append
    for x = 0 < CHUNKS
        get OFFSETX long
        get SIZEX long
        get ZSIZEX long
        math OFFSETX += OFFSET
        if ZSIZEX & 0x10000000
            print "Error: type2 0x10000000 not supported"
            cleanexit
        elif ZSIZEX & 0x20000000
            math ZSIZEX &= 0x0fffffff
            clog MEMORY_FILE OFFSETX ZSIZEX SIZEX
        elif ZSIZEX & 0x40000000
            print "Error: type2 0x40000000 not supported"
            cleanexit
        elif ZSIZEX & 0x80000000
            print "Error: type2 0x80000000 not supported"
            cleanexit
        else
            log MEMORY_FILE OFFSETX SIZEX
        endif
    next x
    append
    log CRC 0 SIZE MEMORY_FILE
    goto TMP
endfunction

note that ui.pak contains a file that is archive wrongly, I mean that the file table claims it's compressed but its decompression fails, so I have added its name/crc to the list of files to skip.
if you encounter errors during the extraction of the other archives it's enough that you add their name where is located the example of "#elif CRC == 12345678" or simply let me know their names and I will tell you what to add in the script

Posted: **Wed Jan 13, 2010 8:39 pm**

Also, read the rules on which upload services are allowed (RAPIDSHARE is not !)

Posted: **Thu Jan 14, 2010 5:01 am**

I am sorry my English is not very good Mr.Mouse. I did not find a suitable space for uploading.
I will continue to upload if there is a suitable space. Thank you for reminding me.Mr.Mouse

to aluigi ：
thanks for you script.
I used your script, but the extract all files out of the same type. I do not know the real name of the file and format.
I think， The image format in data.pak file is the "DDS", the model format is "mesh",
In "UI.pak" file ,the image format is"TGA".
There are other formats, such as". Ani" ". Bsp" ". Block" and so on.
You can look at "dat.rar".
data.rar - 1.00MB
If you need, I will provide more resources.
Hope that these examples to give you the help.
Very very thank you.

Posted: **Thu Jan 14, 2010 2:39 pm**

I forgot to say that the filenames are not stored in the archive, the only thing stored is the crc of the filenames so that's the only thing you can use as name

Posted: **Fri Jan 22, 2010 12:11 pm**

sorry, I did not complete it.
BMS script is very difficult to me . I think I have to spend some time to learn it.
Hope to see aluigi and more friends to help.

Posted: **Fri Jan 22, 2010 9:15 pm**

I don't understand what's the problem now:
there are NO filenames stored in the archives.

if you have other problems with the extraction, be more specific

Posted: **Sun Jul 13, 2014 12:55 pm**

error when unpacking with QuickBMS on new Client (version 3.3.3)

can aluigi update the quickbms script ?

Thx

XeNTaX

Need help for JX3ONLINE PAK file !!

Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!

Re: Need help for JX3ONLINE PAK file !!